CAD用户的福音！自制一个低成本六自由度的 “3DConnection SpaceMouse”

DF创客社区

2023-01-12

导读：提升效率的好工具

【点击上方「蓝字」关注DF创客社区，一起成为技术颜控】

传统鼠标是所有2D/3D CAD画图工作站的重要组成部分。它重量轻，而且易于操作。然而从人机工程学的角度来看，它却有一个很明显的缺点——你总是需要用同一只手操作它来完成所有的任务。当大量使用鼠标进行重复性的操作时，这可能导致疼痛和鼠标手，也称为RSI（重复性劳损）。

使用3D鼠标可以防止这些症状，同时使你的CAD工作流程更加高效和健康。

以上内容来自SpaceMouse官网。

一个重度的CAD工作者当然需要一款好用的3D鼠标，我们今天就来介绍自己DIY一个！

一个同时支持6个自由度的3D打印软件专用鼠标，而且非常容易组装。

相关按键的绑定可以在源代码中更改，支持在Linux、Windows和macOS上使用。

作者提供了两种类型的底座（倾斜型和水平型）

▼ 演示效果

材料

三个模拟操纵杆传感器（带电路板）
Pro Micro（基于ATmega 32U4的微控制器，兼容Arduino Leonardo）
各种长度的2毫米自攻螺丝

打印材料

打印三份 ball-joint.stl
打印 knob.stl需要支撑，如果倒放的话可以不需要支撑。

所有的stl文件可以在文末打包下载。

组装并测试

选择足够长度的螺丝。对ball-joint.stl，建议用最短的螺钉（M2 x 4mm）
使用Arduino IDE将程序 mouse.ino 烧录到 Pro Micro 微控制器上
连接模拟操纵杆传感器和Pro Micro
修改代码好让与你的CAD软件一起使用（目前的代码是适合Blender的）
把控制器安装在三脚架上并进行测试

#include "Mouse.h"
#include "Keyboard.h"

#define DELAY 15 // motion sending cycle
#define DEAD_THRES 0 // threshold to ignore small motion
#define SPEED_PARAM 400 // larger is slower

#define DOF 6
#define TX 0 // translation X
#define TY 1 // translation Y
#define TZ 2 // translation Z
#define RX 3 // rotation X
#define RY 4 // rotation Y
#define RZ 5 // rotation Z

// ports of analog input for joysticks
int port[DOF] = {A0, A2, A6, A1, A3, A7};

// conversion matrix from sensor input to rigid motion
int coeff[DOF][DOF] = {
  { 0,  0,  0,-10,-10, 20}, // TX
  { 0,  0,  0,-17, 17,  0}, // TY
  {-3, -3, -3,  0,  0,  0}, // TZ
  {-6,  6,  0,  0,  0,  0}, // RY
  { 3,  3, -6,  0,  0,  0}, // RX
  { 0,  0,  0,  3,  3,  3}, // RZ
};

int origin[DOF]; // initial sensor values

void setup() {
  Mouse.begin();
  Keyboard.begin();
  delay(300);
  for(int i = 0; i < DOF; i++) {
    origin[i] = analogRead(port[i]);
  }
}

int sx, sy, sw;
void move(int x, int y, int w) {
  if(x > DEAD_THRES)
    x -= DEAD_THRES;
  else if(x < -DEAD_THRES)
    x += DEAD_THRES;
  else
    x = 0;

  if(y > DEAD_THRES)
    y -= DEAD_THRES;
  else if(y < -DEAD_THRES)
    y += DEAD_THRES;
  else
    y = 0;

  if(w > DEAD_THRES)
    w -= DEAD_THRES;
  else if(w < -DEAD_THRES)
    w += DEAD_THRES;
  else
    w = 0;

  Mouse.move(x, y, w);

  sx += x;
  sy += y;
  sw += w;
}

// return mouse pointer to the original position
void resetMove(void) {
    Mouse.move(-sx, -sy, -sw);
    sx = 0;
    sy = 0;
    sw = 0;
}

void loop() {
  int sv[DOF]; // sensor value
  int mv[DOF]; // motion vector
  int moveFlag = false;

  for(int i = 0; i < DOF; i++) {
    sv[i] = analogRead(port[i]) - origin[i];
  }

  for(int i = 0; i < DOF; i++) {
    mv[i] = 0;
    for(int j = 0; j < DOF; j++) {
      mv[i] += coeff[i][j] * sv[j];
    }
    mv[i] /= SPEED_PARAM;
    if(mv[i] > 127) {
      mv[i] = 127;
    }
    else if(mv[i] < -128) {
      mv[i] = -128;
    }
  }

  if(abs(mv[RX]) > DEAD_THRES || abs(mv[RY]) > DEAD_THRES) {
    Mouse.press(MOUSE_MIDDLE);
    move(mv[RX], mv[RY], 0);
    Mouse.release(MOUSE_MIDDLE);
  }

  if(abs(mv[TX]) > DEAD_THRES || abs(mv[TY]) > DEAD_THRES) {
    Keyboard.press(KEY_LEFT_SHIFT);
    Mouse.press(MOUSE_MIDDLE);
    move(mv[TX], mv[TY], 0);
    Keyboard.releaseAll();
    Mouse.release(MOUSE_MIDDLE);
  }

  if(abs(mv[TZ]) > DEAD_THRES) {
    Keyboard.press(KEY_LEFT_CTRL);
    Mouse.press(MOUSE_MIDDLE);
    move(0, mv[TZ], 0);
    Keyboard.releaseAll();
    Mouse.release(MOUSE_MIDDLE);
  }

  resetMove();

  delay(DELAY);
}