不同格式的数据读入Mata方法总结（三）

在之前的推文中我们介绍了.mmat 格式、dta格式和txt格式的数据导入Mata。今天我们为大家介绍Excel文件导入Mata的方法。

首先，我们生成一个excel文件：

sysuse auto,clear
export excel using d:\mywork5,replace

接着，我们将文件mywork5.xls导入Mata:

mata
       b = xl() 
       b.load_book ("d:\mywork5.xls")
       b.set_sheet("Sheet1")
       val1 = b.get_string(1,1)
       val1
       val2 = b.get_number(1,2)
       val2
       cols = (2,6)
       cells1 = b.get_string(1,cols)
       cells1
       rows = (1,3)
       cols = (2,4)
       cells2 = b.get_number(rows,cols)
       cells2
end

注：

xl()：Mata中导入Excel文件的类函数
load_book：加载Excel文件
set_sheet：指定所要选择的Excel子表
get_string(1,1)：读入第一行第一列的字符
get_number(1,2)：读入第一行第二列的数值
rows = (n,m)：选定的行数是n-m行
cols = (n,m)：选定的列数是n-m列

得到：

可以看到，以上程序能实现我们提取单个观测值或是某一范围数值的目标。

那如果我们想批量导入多个excel文件，该如何实现呢？现在我们生成3个excel文件，每个excel文件中包含2个子表，每个表中有3个变量、10个观测值，程序如下：

clear
cap mkdir d:/sample/
cd d:/sample
sysuse auto,clear
keep price mpg rep78
keep in 1/10
forvalue i = 1(1)3 {
    forvalue j = 1(1)2{
           export excel using temp`i'.xls,sheet(Sheet`j')
    }
}

接下来，我们将这3个excel表格导入Mata，程序如下：

mata
       mata clear
       b = xl()
       cells=J(1, 3, NULL)  //生成一个1行3列的空矩阵cells
       for(i=1;i<=3;i++) {  //循环读入3个excel文件
           b.load_book (sprintf("d:/sample/temp%g.xls",i)) //sprintf()函数用于格式化字符串的写法，%g这里是用来把1，2，3分别赋到temp后，使其变成temp1,temp2,temp3
           cells[i]=&J(1,2, NULL)  //生成一个指向1行2列空矩阵的指针cells[i]
           sheets = b.get_sheets()  //提取excel文件中的子表个数
           for(j=1;j<=rows(sheets);j++) {  //循环读入excel文件中的子表
               b.set_sheet(sheets[j])
               (*cells[i])[j] = &b.get_number((1,10),(1,3))  //指针的相关内容详见推文《浩如烟海，细若指针》。其中，*cells[i]=* &J(1,2, NULL)= J(1,2, NULL)，*cells[i])[j]表示指向J(1,2, NULL)的第j列，则这一行命令表示是把第i个表格中第j个sheet的1-10行1-3列里的内容储存到*cells[i])[j]中，当然这里我们知道变量个数和观测值个数是3列10行，如果不知道可以设置为excel文件的最大行列数为256
           }
        }
    M = (*(*cells[1])[1]\*(*cells[1])[2]\*(*cells[2])[1]\*(*cells[2])[2]\*(*cells[3])[1]\*(*cells[3])[2])  //(*(*cells[1])[1]表示第1个表格中第1个sheet的1-10行1-3列里的内容，\表示纵向拼接。
    M
end

得到：

可以看到，3个Excel文件中6个子表合并完成，共有60个观测值。